GitHub-Mirror/Star64_linux
2
0
Fork 0
mirror of https://github.com/Fishwaldo/Star64_linux.git synced 2025-06-22 06:32:08 +00:00
Code Issues Projects Releases Packages Wiki Activity Actions

scripts/coccinelle/misc/memcpy-assign.cocci: Replace memcpy with struct assignment

Browse source 
There are error-prone memcpy() that can be replaced by struct
assignment that are type-safe and much easier to read. This semantic
patch looks for memcpy() that can be replaced by struct assignment.

Inspired by patches sent by Ezequiel Garcia <elezegarcia@gmail.com>

Signed-off-by: Peter Senna Tschudin <peter.senna@gmail.com>
Signed-off-by: Michal Marek <mmarek@suse.cz>
This commit is contained in:
Peter Senna Tschudin 2013-01-23 20:06:30 -02:00 • committed by Michal Marek
parent e0367a6156
commit ff3771cb71
1 changed files with 103 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

103
scripts/coccinelle/misc/memcpy-assign.cocci Normal file
View file

@ -0,0 +1,103 @@
//
// Replace memcpy with struct assignment.
//
// Confidence: High
// Copyright: (C) 2012 Peter Senna Tschudin, INRIA/LIP6. GPLv2.
// URL: http://coccinelle.lip6.fr/
// Comments:
// Options: --no-includes --include-headers
virtual patch
virtual report
virtual context
virtual org
@r1 depends on !patch@
identifier struct_name;
struct struct_name to;
struct struct_name from;
struct struct_name *top;
struct struct_name *fromp;
position p;
@@
memcpy@p(\(&(to)\|top\), \(&(from)\|fromp\), \(sizeof(to)\|sizeof(from)\|sizeof(struct struct_name)\|sizeof(*top)\|sizeof(*fromp)\))
@script:python depends on report@
p << r1.p;
@@
coccilib.report.print_report(p[0],"Replace memcpy with struct assignment")
@depends on context@
position r1.p;
@@
*memcpy@p(...);
@script:python depends on org@
p << r1.p;
@@
cocci.print_main("Replace memcpy with struct assignment",p)
@depends on patch@
identifier struct_name;
struct struct_name to;
struct struct_name from;
@@
(
-memcpy(&(to), &(from), sizeof(to));
+to = from;
|
-memcpy(&(to), &(from), sizeof(from));
+to = from;
|
-memcpy(&(to), &(from), sizeof(struct struct_name));
+to = from;
)
@depends on patch@
identifier struct_name;
struct struct_name to;
struct struct_name *from;
@@
(
-memcpy(&(to), from, sizeof(to));
+to = *from;
|
-memcpy(&(to), from, sizeof(*from));
+to = *from;
|
-memcpy(&(to), from, sizeof(struct struct_name));
+to = *from;
)
@depends on patch@
identifier struct_name;
struct struct_name *to;
struct struct_name from;
@@
(
-memcpy(to, &(from), sizeof(*to));
+ *to = from;
|
-memcpy(to, &(from), sizeof(from));
+ *to = from;
|
-memcpy(to, &(from), sizeof(struct struct_name));
+ *to = from;
)
@depends on patch@
identifier struct_name;
struct struct_name *to;
struct struct_name *from;
@@
(
-memcpy(to, from, sizeof(*to));
+ *to = *from;
|
-memcpy(to, from, sizeof(*from));
+ *to = *from;
|
-memcpy(to, from, sizeof(struct struct_name));
+ *to = *from;
)